Visual Basic サンプル集

フォルダーを削除する

2020/9/13

→ C# のサンプルに切り替える

フォルダーを削除する

IO.Directory.Delete("C:\FileTest\FolderA", True)

ゴミ箱に入らず、永久に削除されます。

フォルダーをゴミ箱に入れる

FileIO.FileSystem.DeleteDirectory("C:\FileTest\FolderA", FileIO.UIOption.OnlyErrorDialogs, FileIO.RecycleOption.SendToRecycleBin, FileIO.UICancelOption.DoNothing)

Windowsでのみ実行できます。

これでもできます。

この例を実行するにはファイルの先頭の方に Imports System.Runtime.InteropServices が必要です。

Public Sub DeleteTest()

    Dim sf As New NativeMethods.SHFILEOPSTRUCT

    sf.wFunc = NativeMethods.FileFuncFlags.FO_DELETE '削除を指示します。
    sf.fFlags = NativeMethods.FILEOP_FLAGS.FOF_ALLOWUNDO '「元に戻す」を有効にします。
    sf.fFlags = sf.fFlags Or NativeMethods.FILEOP_FLAGS.FOF_NOERRORUI 'エラー画面を表示しません。
    sf.fFlags = sf.fFlags Or NativeMethods.FILEOP_FLAGS.FOF_SILENT '進捗ダイアログを表示しません。
    sf.fFlags = sf.fFlags Or NativeMethods.FILEOP_FLAGS.FOF_NOCONFIRMATION '削除確認ダイアログを表示しません。
    sf.pFrom = "C:\FileTest\FolderA" & vbNullChar

    Dim result As Integer
    result = NativeMethods.SHFileOperation(sf)

    If result = 0 Then
        Debug.WriteLine("成功")
    Else
        Debug.WriteLine("失敗。" & result)
    End If

End Sub

Public Class NativeMethods

    ''' <summary>
    ''' ファイルをコピー・移動・削除・名前変更します。
    ''' </summary>
    ''' <param name="lpFileOp"></param>
    ''' <returns>正常時0。異常時の値の意味は https://docs.microsoft.com/ja-jp/windows/win32/api/shellapi/nf-shellapi-shfileoperationa を参照。</returns>
    <DllImport("shell32.dll", SetLastError:=True, CharSet:=CharSet.Unicode)>
    Public Shared Function SHFileOperation(<MarshalAs(UnmanagedType.Struct)> ByRef lpFileOp As SHFILEOPSTRUCT) As Integer
    End Function

    <StructLayout(LayoutKind.Sequential, CharSet:=CharSet.Unicode)>
    Public Structure SHFILEOPSTRUCT
        Public hwnd As IntPtr
        <MarshalAs(UnmanagedType.U4)> Public wFunc As FileFuncFlags
        <MarshalAs(UnmanagedType.LPWStr)> Public pFrom As String
        <MarshalAs(UnmanagedType.LPWStr)> Public pTo As String
        <MarshalAs(UnmanagedType.U2)> Public fFlags As FILEOP_FLAGS
        <MarshalAs(UnmanagedType.Bool)> Public ffAnyOperationsAborted As Boolean
        Public hNameMappings As IntPtr 'FOF_WANTMAPPINGHANDLEフラグとともに使用します。
        <MarshalAs(UnmanagedType.LPWStr)> Public lplpszProgressTitle As String 'FOF_SIMPLEPROGRESSフラグとともに使用します。
    End Structure

    Public Enum FileFuncFlags
        ''' <summary>pFrom から pTo にファイルを移動します。</summary>
        FO_MOVE = &H1
        ''' <summary>pFrom から pTo にファイルをコピーします。</summary>
        FO_COPY = &H2
        ''' <summary>pFrom からファイルを削除します。</summary>
        FO_DELETE = &H3
        ''' <summary>pFrom のファイルの名前を変更します。複数ファイルを対象とする場合は FO_MOVE を使用します。</summary>
        FO_RENAME = &H4
    End Enum

    <Flags>
    Public Enum FILEOP_FLAGS As Short
        ''' <summary>pToにはpFromに１対１で対応する複数のコピー先を指定します。</summary>
        FOF_MULTIDESTFILES = &H1
        ''' <summary>このフラグは使用しません。</summary>
        FOF_CONFIRMMOUSE = &H2
        ''' <summary>進捗状況のダイアログを表示しません。</summary>
        FOF_SILENT = &H4
        ''' <summary>同名のファイルが既に存在する場合、新しい名前を付けます。</summary>
        FOF_RENAMEONCOLLISION = &H8
        ''' <summary>確認ダイアログを表示せず、すべて「はい」を選択したものとします。</summary>
        FOF_NOCONFIRMATION = &H10
        ''' <summary>FOF_RENAMEONCOLLISIONフラグによるファイル名の衝突回避が発生した場合、SHFILEOPSTRUCT.hNameMappingsに新旧ファイル名の情報を格納します。この情報はSHFreeNameMappingsを使って開放する必要があります。</summary>
        FOF_WANTMAPPINGHANDLE = &H20
        ''' <summary>可能であれば、操作を元に戻せるようにします。</summary>
        FOF_ALLOWUNDO = &H40
        ''' <summary>ワイルドカードが使用された場合、ファイルのみを対象とします。</summary>
        FOF_FILESONLY = &H80
        ''' <summary>進捗状況のダイアログを表示しますが、個々のファイル名は表示しません。</summary>
        FOF_SIMPLEPROGRESS = &H100
        ''' <summary>新しいフォルダーの作成する前にユーザーに確認しません。</summary>
        FOF_NOCONFIRMMKDIR = &H200
        ''' <summary>エラーが発生してもダイアログを表示しません。</summary>
        FOF_NOERRORUI = &H400
        ''' <summary>ファイルのセキュリティ属性はコピーしません。コピー後のファイルはコピー先のフォルダーのセキュリティ属性を引き継ぎます。</summary>
        FOF_NOCOPYSECURITYATTRIBS = &H800
        ''' <summary>サブディレクトリーを再帰的に処理しません。これは既定の動作です。</summary>
        FOF_NORECURSION = &H1000
        ''' <summary>グループとして連結しているファイルは移動しません。指定されたファイルだけを移動します。</summary>
        FOF_NO_CONNECTED_ELEMENTS = &H2000
        ''' <summary>ファイルが恒久的に削除される場合、警告を表示します。このフラグはFOF_NOCONFIRMATIONより優先されます。 </summary>
        FOF_WANTNUKEWARNING = &H4000
        ''' <summary>UIを表示しません。</summary>
        FOF_NO_UI = FOF_SILENT Or FOF_NOCONFIRMATION Or FOF_NOERRORUI Or FOF_NOCONFIRMMKDIR

    End Enum

End Class

Windowsでのみ実行できます。(.NET Framework , .NET Core, .Net 5以降すべてで実行できます。)
このサンプルで使用している NativeMethods クラスは他のサンプルで使用しているものと完全に同じです。

ダイアログを表示して削除する

この例は時間がかかる削除の進捗状況を表示するダイアログや、削除の確認ダイアログなどを表示します。

すぐに削除が終わる場合は進捗状況のダイアログは表示されません。

FileIO.FileSystem.DeleteDirectory("C:\FileTest\FolderA", FileIO.UIOption.AllDialogs, FileIO.RecycleOption.DeletePermanently)

削除に時間がかかる場合、進捗状況のダイアログを表示します。(この画像は移動ではなくコピーの画像を流用しています。)

ファイルコピーのダイアログ

何かエラーが発生した場合、エラーを表示します。
Windowsでのみ実行できます。
ゴミ箱に入らず、永久に削除されます。

次の例でもダイアログを表示してフォルダーを削除します。

表示するダイアログの種類はフラグで制御します。サンプル内にコメントの見て行単位で削除できるようにしてありますので適宜調整してください。

この例を実行するにはファイルの先頭の方に Imports System.Runtime.InteropServices が必要です。

Public Sub DeleteTest()

    Dim sf As New NativeMethods.SHFILEOPSTRUCT

    sf.wFunc = NativeMethods.FileFuncFlags.FO_DELETE '削除を指示します。
    'sf.fFlags = sf.fFlags Or NativeMethods.FILEOP_FLAGS.FOF_NOCONFIRMATION 'この行を有効にすると、確認ダイアログを表示しません。
    'sf.fFlags = sf.fFlags Or NativeMethods.FILEOP_FLAGS.FOF_NOERRORUI 'この行を有効にすると、エラーダイアログを表示しません。
    sf.pFrom = "C:\FileTest\FolderA" & vbNullChar

    Dim result As Integer
    result = NativeMethods.SHFileOperation(sf)

    If result = 0 Then
        Debug.WriteLine("成功")
    Else
        Debug.WriteLine("失敗。" & result)
    End If

End Sub

Public Class NativeMethods

    ''' <summary>
    ''' ファイルをコピー・移動・削除・名前変更します。
    ''' </summary>
    ''' <param name="lpFileOp"></param>
    ''' <returns>正常時0。異常時の値の意味は https://docs.microsoft.com/ja-jp/windows/win32/api/shellapi/nf-shellapi-shfileoperationa を参照。</returns>
    <DllImport("shell32.dll", SetLastError:=True, CharSet:=CharSet.Unicode)>
    Public Shared Function SHFileOperation(<MarshalAs(UnmanagedType.Struct)> ByRef lpFileOp As SHFILEOPSTRUCT) As Integer
    End Function

    <StructLayout(LayoutKind.Sequential, CharSet:=CharSet.Unicode)>
    Public Structure SHFILEOPSTRUCT
        Public hwnd As IntPtr
        <MarshalAs(UnmanagedType.U4)> Public wFunc As FileFuncFlags
        <MarshalAs(UnmanagedType.LPWStr)> Public pFrom As String
        <MarshalAs(UnmanagedType.LPWStr)> Public pTo As String
        <MarshalAs(UnmanagedType.U2)> Public fFlags As FILEOP_FLAGS
        <MarshalAs(UnmanagedType.Bool)> Public ffAnyOperationsAborted As Boolean
        Public hNameMappings As IntPtr 'FOF_WANTMAPPINGHANDLEフラグとともに使用します。
        <MarshalAs(UnmanagedType.LPWStr)> Public lplpszProgressTitle As String 'FOF_SIMPLEPROGRESSフラグとともに使用します。
    End Structure

    Public Enum FileFuncFlags
        ''' <summary>pFrom から pTo にファイルを移動します。</summary>
        FO_MOVE = &H1
        ''' <summary>pFrom から pTo にファイルをコピーします。</summary>
        FO_COPY = &H2
        ''' <summary>pFrom からファイルを削除します。</summary>
        FO_DELETE = &H3
        ''' <summary>pFrom のファイルの名前を変更します。複数ファイルを対象とする場合は FO_MOVE を使用します。</summary>
        FO_RENAME = &H4
    End Enum

    <Flags>
    Public Enum FILEOP_FLAGS As Short
        ''' <summary>pToにはpFromに１対１で対応する複数のコピー先を指定します。</summary>
        FOF_MULTIDESTFILES = &H1
        ''' <summary>このフラグは使用しません。</summary>
        FOF_CONFIRMMOUSE = &H2
        ''' <summary>進捗状況のダイアログを表示しません。</summary>
        FOF_SILENT = &H4
        ''' <summary>同名のファイルが既に存在する場合、新しい名前を付けます。</summary>
        FOF_RENAMEONCOLLISION = &H8
        ''' <summary>確認ダイアログを表示せず、すべて「はい」を選択したものとします。</summary>
        FOF_NOCONFIRMATION = &H10
        ''' <summary>FOF_RENAMEONCOLLISIONフラグによるファイル名の衝突回避が発生した場合、SHFILEOPSTRUCT.hNameMappingsに新旧ファイル名の情報を格納します。この情報はSHFreeNameMappingsを使って開放する必要があります。</summary>
        FOF_WANTMAPPINGHANDLE = &H20
        ''' <summary>可能であれば、操作を元に戻せるようにします。</summary>
        FOF_ALLOWUNDO = &H40
        ''' <summary>ワイルドカードが使用された場合、ファイルのみを対象とします。</summary>
        FOF_FILESONLY = &H80
        ''' <summary>進捗状況のダイアログを表示しますが、個々のファイル名は表示しません。</summary>
        FOF_SIMPLEPROGRESS = &H100
        ''' <summary>新しいフォルダーの作成する前にユーザーに確認しません。</summary>
        FOF_NOCONFIRMMKDIR = &H200
        ''' <summary>エラーが発生してもダイアログを表示しません。</summary>
        FOF_NOERRORUI = &H400
        ''' <summary>ファイルのセキュリティ属性はコピーしません。コピー後のファイルはコピー先のフォルダーのセキュリティ属性を引き継ぎます。</summary>
        FOF_NOCOPYSECURITYATTRIBS = &H800
        ''' <summary>サブディレクトリーを再帰的に処理しません。これは既定の動作です。</summary>
        FOF_NORECURSION = &H1000
        ''' <summary>グループとして連結しているファイルは移動しません。指定されたファイルだけを移動します。</summary>
        FOF_NO_CONNECTED_ELEMENTS = &H2000
        ''' <summary>ファイルが恒久的に削除される場合、警告を表示します。このフラグはFOF_NOCONFIRMATIONより優先されます。 </summary>
        FOF_WANTNUKEWARNING = &H4000
        ''' <summary>UIを表示しません。</summary>
        FOF_NO_UI = FOF_SILENT Or FOF_NOCONFIRMATION Or FOF_NOERRORUI Or FOF_NOCONFIRMMKDIR

    End Enum

End Class

Windowsでのみ実行できます。(.NET Framework , .NET Core, .Net 5以降すべてで実行できます。)
何かエラーが発生した場合、エラーを表示します。
このサンプルで使用している NativeMethods クラスは他のサンプルで使用しているものと完全に同じです。
ゴミ箱に入らず、永久に削除されます。