Visual Basic サンプル集

ファイルを１つ移動する

2020/8/30

→ C# のサンプルに切り替える

ファイルを単純に移動する

この例は C:\FileTest\FolderA\test.txt を C:\FileTest\FolderB\test.txt に移動します。

IO.File.Move("C:\FileTest\FolderA\test.txt", "C:\FileTest\FolderB\test.txt")

移動先のファイルが既に存在する場合、エラーにします。

これでもできます。

Dim file As New IO.FileInfo("C:\FileTest\FolderA\test.txt")
file.MoveTo("C:\FileTest\FolderB\test.txt")

移動先のファイルが既に存在する場合、エラーにします。

ファイルを上書き移動する

この例は C:\FileTest\FolderA\test.txt を C:\FileTest\FolderB\test.txt に移動して、移動先に同名のファイルが既にある場合上書きします。

IO.File.Move("C:\FileTest\FolderA\test.txt", "C:\FileTest\FolderB\test.txt", True)

移動先のファイルが既に存在する場合、上書きします。

これでもできます。

Dim file As New IO.FileInfo("C:\FileTest\FolderA\test.txt")
file.MoveTo("C:\FileTest\FolderB\test.txt", True)

移動先のファイルが既に存在する場合、上書きします。

移動先のフォルダーがない場合作成して、ファイルを上書き移動する

Dim fileFrom As String = "C:\FileTest\FolderA\test.txt"
Dim fileTo As String = "C:\FileTest\FolderB\test.txt"

'移動先のフォルダーが存在するか確認し、なければ作成します。
Dim targetFolder As String = IO.Path.GetDirectoryName(fileTo)
If IO.Directory.Exists(targetFolder) = False Then
IO.Directory.CreateDirectory(targetFolder)
End If

IO.File.Move(fileFrom, fileTo, True)

移動先のファイルが既に存在する場合、上書きします。

ダイアログを表示して移動する

この例は時間がかかる移動の状況を表示するダイアログや、上書きの確認ダイアログなどを表示します。

何事もなくすぐに移動が終わる場合はダイアログが表示されません。

FileIO.FileSystem.MoveFile("C:\FileTest\FolderA\test.txt", "C:\FileTest\FolderB\test.txt", FileIO.UIOption.AllDialogs, FileIO.UICancelOption.DoNothing)

移動に時間がかかる場合、進捗状況のダイアログを表示します。(この画像は移動ではなくコピーの画像を流用しています。)

ファイルコピーのダイアログ

移動先にファイルが既に存在する場合、どのように処理するかユーザーに確認します。(この画像は移動ではなくコピーの画像を流用しています。)

Windows7の上書き確認ダイアログ

何かエラーが発生した場合、エラーを表示します。
Windowsでのみ実行できます。

次の例でも、ダイアログを表示してファイルを移動します。

この例を実行するにはファイルの先頭の方に Imports System.Runtime.InteropServices が必要です。

Public Sub MoveTest()

    Dim sf As New NativeMethods.SHFILEOPSTRUCT

    sf.wFunc = NativeMethods.FileFuncFlags.FO_MOVE '移動を指示します。
    sf.pFrom = "C:\FileTest\FolderA\test.txt" & vbNullChar
    sf.pTo = "C:\FileTest\FolderB\test.txt" & vbNullChar

    Dim result As Integer
    result = NativeMethods.SHFileOperation(sf)

    If result = 0 Then
        Debug.WriteLine("成功")
    Else
        Debug.WriteLine("失敗。" & result)
    End If

End Sub

Public Class NativeMethods

    ''' <summary>
    ''' ファイルをコピー・移動・削除・名前変更します。
    ''' </summary>
    ''' <param name="lpFileOp"></param>
    ''' <returns>正常時0。異常時の値の意味は https://docs.microsoft.com/ja-jp/windows/win32/api/shellapi/nf-shellapi-shfileoperationa を参照。</returns>
    <DllImport("shell32.dll", SetLastError:=True, CharSet:=CharSet.Unicode)>
    Public Shared Function SHFileOperation(<MarshalAs(UnmanagedType.Struct)> ByRef lpFileOp As SHFILEOPSTRUCT) As Integer
    End Function

    <StructLayout(LayoutKind.Sequential, CharSet:=CharSet.Unicode)>
    Public Structure SHFILEOPSTRUCT
        Public hwnd As IntPtr
        <MarshalAs(UnmanagedType.U4)> Public wFunc As FileFuncFlags
        <MarshalAs(UnmanagedType.LPWStr)> Public pFrom As String
        <MarshalAs(UnmanagedType.LPWStr)> Public pTo As String
        <MarshalAs(UnmanagedType.U2)> Public fFlags As FILEOP_FLAGS
        <MarshalAs(UnmanagedType.Bool)> Public ffAnyOperationsAborted As Boolean
        Public hNameMappings As IntPtr 'FOF_WANTMAPPINGHANDLEフラグとともに使用します。
        <MarshalAs(UnmanagedType.LPWStr)> Public lplpszProgressTitle As String 'FOF_SIMPLEPROGRESSフラグとともに使用します。
    End Structure

    Public Enum FileFuncFlags
        ''' <summary>pFrom から pTo にファイルを移動します。</summary>
        FO_MOVE = &H1
        ''' <summary>pFrom から pTo にファイルをコピーします。</summary>
        FO_COPY = &H2
        ''' <summary>pFrom からファイルを削除します。</summary>
        FO_DELETE = &H3
        ''' <summary>pFrom のファイルの名前を変更します。複数ファイルを対象とする場合は FO_MOVE を使用します。</summary>
        FO_RENAME = &H4
    End Enum

    <Flags>
    Public Enum FILEOP_FLAGS As Short
        ''' <summary>pToにはpFromに１対１で対応する複数のコピー先を指定します。</summary>
        FOF_MULTIDESTFILES = &H1
        ''' <summary>このフラグは使用しません。</summary>
        FOF_CONFIRMMOUSE = &H2
        ''' <summary>進捗状況のダイアログを表示しません。</summary>
        FOF_SILENT = &H4
        ''' <summary>同名のファイルが既に存在する場合、新しい名前を付けます。</summary>
        FOF_RENAMEONCOLLISION = &H8
        ''' <summary>確認ダイアログを表示せず、すべて「はい」を選択したものとします。</summary>
        FOF_NOCONFIRMATION = &H10
        ''' <summary>FOF_RENAMEONCOLLISIONフラグによるファイル名の衝突回避が発生した場合、SHFILEOPSTRUCT.hNameMappingsに新旧ファイル名の情報を格納します。この情報はSHFreeNameMappingsを使って開放する必要があります。</summary>
        FOF_WANTMAPPINGHANDLE = &H20
        ''' <summary>可能であれば、操作を元に戻せるようにします。</summary>
        FOF_ALLOWUNDO = &H40
        ''' <summary>ワイルドカードが使用された場合、ファイルのみを対象とします。</summary>
        FOF_FILESONLY = &H80
        ''' <summary>進捗状況のダイアログを表示しますが、個々のファイル名は表示しません。</summary>
        FOF_SIMPLEPROGRESS = &H100
        ''' <summary>新しいフォルダーの作成する前にユーザーに確認しません。</summary>
        FOF_NOCONFIRMMKDIR = &H200
        ''' <summary>エラーが発生してもダイアログを表示しません。</summary>
        FOF_NOERRORUI = &H400
        ''' <summary>ファイルのセキュリティ属性はコピーしません。コピー後のファイルはコピー先のフォルダーのセキュリティ属性を引き継ぎます。</summary>
        FOF_NOCOPYSECURITYATTRIBS = &H800
        ''' <summary>サブディレクトリーを再帰的に処理しません。これは既定の動作です。</summary>
        FOF_NORECURSION = &H1000
        ''' <summary>グループとして連結しているファイルは移動しません。指定されたファイルだけを移動します。</summary>
        FOF_NO_CONNECTED_ELEMENTS = &H2000
        ''' <summary>ファイルが恒久的に削除される場合、警告を表示します。このフラグはFOF_NOCONFIRMATIONより優先されます。 </summary>
        FOF_WANTNUKEWARNING = &H4000
        ''' <summary>UIを表示しません。</summary>
        FOF_NO_UI = FOF_SILENT Or FOF_NOCONFIRMATION Or FOF_NOERRORUI Or FOF_NOCONFIRMMKDIR

    End Enum

End Class

Windowsでのみ実行できます。
何かエラーが発生した場合、エラーを表示します。
このサンプルで使用している NativeMethods クラスは他のサンプルで使用しているものと完全に同じです。

この例の引数を変更して、「元に戻す」を可能にしたり、同名のファイルが存在する場合ファイル名を変更するなど動作をカスタマイズできます。ファイルを１つコピーするでいくつかサンプルを紹介します。