Visual Basic サンプル集

フォルダーをコピーする

2020/8/30

→ C# のサンプルに切り替える

フォルダーをコピーする

FileIO.FileSystem.CopyDirectory("C:\FileTest\FolderA", "C:\FileTest\FolderB", True)

コピー先のフォルダーが既に存在する場合、そのフォルダーや中のファイルは削除されずそのまま残ります。
コピー先に同名のファイルが既に存在する場合、上書きします。
コピー先のフォルダーが存在しない場合、フォルダーを作成します。

ダイアログを表示してコピーする

この例は時間がかかるコピーの状況を表示するダイアログや、上書きの確認ダイアログなどを表示します。

何事もなくすぐにコピーが終わる場合はダイアログが表示されません。

FileIO.FileSystem.CopyDirectory("C:\FileTest\FolderA", "C:\FileTest\FolderB", FileIO.UIOption.AllDialogs, FileIO.UICancelOption.DoNothing)

コピーに時間がかかる場合、進捗状況のダイアログを表示します。

ファイルコピーのダイアログ

コピー先のファイルが既に存在する場合、どのように処理するかユーザーに確認します。

Windows7の上書き確認ダイアログ

何かエラーが発生した場合、エラーを表示します。
Windowsでのみ実行できます。

次の例でも、ダイアログを表示してフォルダーをコピーします。

表示するダイアログの種類はフラグで制御します。サンプル内にコメントの見て行単位で削除できるようにしてありますので適宜調整してください。

この例を実行するにはファイルの先頭の方に Imports System.Runtime.InteropServices が必要です。

Public Sub CopyTest()

    Dim folderFrom As String = "C:\FileTest\FolderA" 'コピー元のフォルダー
    Dim folderTo As String = "C:\FileTest\FolderB" 'コピー先のフォルダー
    Dim filePattern As String = "*"

    Dim sf As New NativeMethods.SHFILEOPSTRUCT

    sf.wFunc = NativeMethods.FileFuncFlags.FO_COPY 'コピーを指示します。
    sf.fFlags = NativeMethods.FILEOP_FLAGS.FOF_MULTIDESTFILES
    sf.fFlags = sf.fFlags Or NativeMethods.FILEOP_FLAGS.FOF_NOCONFIRMATION '上書き確認ダイアログを表示せず、上書きします。
    sf.fFlags = sf.fFlags Or NativeMethods.FILEOP_FLAGS.FOF_NOCONFIRMMKDIR 'フォルダー作成の確認ダイアログを表示せずフォルダーを作成します。
    sf.fFlags = sf.fFlags Or NativeMethods.FILEOP_FLAGS.FOF_NOERRORUI 'エラーダイアログを表示しません。

    Dim foldersFrom As New List(Of String)
    Dim foldersTo As New List(Of String)
    foldersFrom.Add(folderFrom & "\" & filePattern)
    foldersTo.Add(folderTo & "\")

    For Each folder In IO.Directory.GetDirectories(folderFrom, "*", IO.SearchOption.AllDirectories)
        foldersFrom.Add(folder & "\" & filePattern)
        foldersTo.Add(folder.Replace(folderFrom, folderTo) & "\")
    Next

    sf.pFrom = String.Join(vbNullChar, foldersFrom) & vbNullChar
    sf.pTo = String.Join(vbNullChar, foldersTo) & vbNullChar

    Dim result As Integer
    result = NativeMethods.SHFileOperation(sf)

    If result = 0 Then
        Debug.WriteLine("成功")
    Else
        Debug.WriteLine("失敗。" & result)
    End If

End Sub

Public Class NativeMethods

    ''' <summary>
    ''' ファイルをコピー・移動・削除・名前変更します。
    ''' </summary>
    ''' <param name="lpFileOp"></param>
    ''' <returns>正常時0。異常時の値の意味は https://docs.microsoft.com/ja-jp/windows/win32/api/shellapi/nf-shellapi-shfileoperationa を参照。</returns>
    <DllImport("shell32.dll", SetLastError:=True, CharSet:=CharSet.Unicode)>
    Public Shared Function SHFileOperation(<MarshalAs(UnmanagedType.Struct)> ByRef lpFileOp As SHFILEOPSTRUCT) As Integer
    End Function

    <StructLayout(LayoutKind.Sequential, CharSet:=CharSet.Unicode)>
    Public Structure SHFILEOPSTRUCT
        Public hwnd As IntPtr
        <MarshalAs(UnmanagedType.U4)> Public wFunc As FileFuncFlags
        <MarshalAs(UnmanagedType.LPWStr)> Public pFrom As String
        <MarshalAs(UnmanagedType.LPWStr)> Public pTo As String
        <MarshalAs(UnmanagedType.U2)> Public fFlags As FILEOP_FLAGS
        <MarshalAs(UnmanagedType.Bool)> Public ffAnyOperationsAborted As Boolean
        Public hNameMappings As IntPtr 'FOF_WANTMAPPINGHANDLEフラグとともに使用します。
        <MarshalAs(UnmanagedType.LPWStr)> Public lplpszProgressTitle As String 'FOF_SIMPLEPROGRESSフラグとともに使用します。
    End Structure

    Public Enum FileFuncFlags
        ''' <summary>pFrom から pTo にファイルを移動します。</summary>
        FO_MOVE = &H1
        ''' <summary>pFrom から pTo にファイルをコピーします。</summary>
        FO_COPY = &H2
        ''' <summary>pFrom からファイルを削除します。</summary>
        FO_DELETE = &H3
        ''' <summary>pFrom のファイルの名前を変更します。複数ファイルを対象とする場合は FO_MOVE を使用します。</summary>
        FO_RENAME = &H4
    End Enum

    <Flags>
    Public Enum FILEOP_FLAGS As Short
        ''' <summary>pToにはpFromに１対１で対応する複数のコピー先を指定します。</summary>
        FOF_MULTIDESTFILES = &H1
        ''' <summary>このフラグは使用しません。</summary>
        FOF_CONFIRMMOUSE = &H2
        ''' <summary>進捗状況のダイアログを表示しません。</summary>
        FOF_SILENT = &H4
        ''' <summary>同名のファイルが既に存在する場合、新しい名前を付けます。</summary>
        FOF_RENAMEONCOLLISION = &H8
        ''' <summary>確認ダイアログを表示せず、すべて「はい」を選択したものとします。</summary>
        FOF_NOCONFIRMATION = &H10
        ''' <summary>FOF_RENAMEONCOLLISIONフラグによるファイル名の衝突回避が発生した場合、SHFILEOPSTRUCT.hNameMappingsに新旧ファイル名の情報を格納します。この情報はSHFreeNameMappingsを使って開放する必要があります。</summary>
        FOF_WANTMAPPINGHANDLE = &H20
        ''' <summary>可能であれば、操作を元に戻せるようにします。</summary>
        FOF_ALLOWUNDO = &H40
        ''' <summary>ワイルドカードが使用された場合、ファイルのみを対象とします。</summary>
        FOF_FILESONLY = &H80
        ''' <summary>進捗状況のダイアログを表示しますが、個々のファイル名は表示しません。</summary>
        FOF_SIMPLEPROGRESS = &H100
        ''' <summary>新しいフォルダーの作成する前にユーザーに確認しません。</summary>
        FOF_NOCONFIRMMKDIR = &H200
        ''' <summary>エラーが発生してもダイアログを表示しません。</summary>
        FOF_NOERRORUI = &H400
        ''' <summary>ファイルのセキュリティ属性はコピーしません。コピー後のファイルはコピー先のフォルダーのセキュリティ属性を引き継ぎます。</summary>
        FOF_NOCOPYSECURITYATTRIBS = &H800
        ''' <summary>サブディレクトリーを再帰的に処理しません。これは既定の動作です。</summary>
        FOF_NORECURSION = &H1000
        ''' <summary>グループとして連結しているファイルは移動しません。指定されたファイルだけを移動します。</summary>
        FOF_NO_CONNECTED_ELEMENTS = &H2000
        ''' <summary>ファイルが恒久的に削除される場合、警告を表示します。このフラグはFOF_NOCONFIRMATIONより優先されます。 </summary>
        FOF_WANTNUKEWARNING = &H4000
        ''' <summary>UIを表示しません。</summary>
        FOF_NO_UI = FOF_SILENT Or FOF_NOCONFIRMATION Or FOF_NOERRORUI Or FOF_NOCONFIRMMKDIR

    End Enum

End Class

Windowsでのみ実行できます。
何かエラーが発生した場合、エラーを表示します。
このサンプルで使用している NativeMethods クラスは他のサンプルで使用しているものと完全に同じです。

この例の引数を変更して、「元に戻す」を可能にしたり、同名のファイルが存在する場合ファイル名を変更するなど動作をカスタマイズできます。ファイルを１つコピーするでいくつかサンプルを紹介します。